経済の波及効果を係数から「見える化」する、
Excelでの産業連関分析の実践手順。

e-Stat で公表されている平成23（2011）年の日本の産業連関表（取引基本表・生産者価格評価表・13部門分類）を使用します。シート名は「元表」とします。この元表から4部門の統合表を作成し、投入係数表と逆行列係数表を作成することが目標です。

13部門を以下の4部門に集約します（部門統合）。

• 第1次産業（農林水産業 1部門）
• 第2次産業（3部門を統合）
• 商業・運輸（2部門を統合）
• サービス他（7部門を統合）

新しいシート「4部門統合表」を挿入し、表の枠組みを作成します。入力が面倒な場合は下のリンクから表組みをセル A1 にコピーしてください。

• 4部門統合表の骨格をコピー

シート「元表」に切り替え、3行目と B 列に行・列を挿入し、識別番号を割り振ります。内生部門（13部門）は 1〜4 を、最終需要部門は 11〜15 を、付加価値部門は 21〜23 を割り当てます。ここではまず内生部門に番号を割り当てます。

最終需要部門（消費:11、投資:12、調整項:13、輸出:14、輸入:15）と付加価値部門（雇用者所得:21、営業余剰:22、その他:23）にも識別番号を入力します。

「4部門統合表」シートに切り替え、セル B16 をアクティブにします。データ タブ → データツール の 統合 をクリックし、統合元範囲に「元表」の識別番号を含む全範囲（セル B3:AF24）を指定、上端行・左端列 両方にチェックして OK。

集計結果を行・列ともに識別番号順に並べ替えます。まず行方向（データ タブ → 並べ替え）、次に列方向（オプション→列単位）で並べ替えます。

単位を揃えます（元表の単位は「100万円」、4部門統合表の単位は「100億円」）。任意のセルに 10000 を入力してコピーし、集計値の範囲を選択して 形式を選択して貼り付け → 除算 で値を 1/10000 に変換します。

集計値を表の正しい位置に移動し、セル C4 にペーストします。行計・列計をエリアごとにオートサムで求め、「総需要」「国内生産額」を計算します。

• M列「総需要」= 中間需要の計 ＋ 最終需要の計
• O列「国内生産額」= 総需要 ＋ 輸入（控除）
• 13行「国内生産額」= 中間投入の計 ＋ 付加価値の計

「4部門統合表」の完成です。

4部門統合表から産業構造をざっと確認します。「国内生産額」を1とした費用構成（帯グラフ）、「総需要」を1とした需要構成（帯グラフ）、最終需要の内訳×産業（マリメッコチャート）、中間需要×中間投入の散布図などが有効な可視化手段です。

投入係数は「ある1単位の商品を製造するのに必要な原材料の投入量」、付加価値率は「1単位の生産に必要な労働・資本の投入量」を意味します。新しいシート「投入係数表A」を用意します（下リンクからセル A1 にコピー可）。

• 投入係数表Aの骨格をコピー

「第1次産業」の交点セル（C4）に下式を入力し、表の最右列→最下行の順にコピーします。

• CELL C4='4部門統合表'!C4/'4部門統合表'!C$13

ここでは輸入による波及分を除いた国内波及のみを考慮する [I-(I-M)A]^-1 型のレオンチェフ逆行列を使用します。新しいシート「～」（投入係数表から逆行列係数表をつなぐ中間シート）に6つの表組みを用意します（下のリンクからセル A1 にコピー可）。

• 逆行列係数表に至る計算の骨格をコピー

STEP1：輸入係数を求めます。調整項の扱いは総務省の資料に準じ、下式で計算します。

分母は〔国内需要－調整項〕

• =ABS('4部門統合表'!N4)/('4部門統合表'!M4-'4部門統合表'!K4-'4部門統合表'!J4)

STEP2：単位行列 I — 同一産業の交点に1、それ以外は0。

• CELL B9=IF(ROWS($A$9:$A9)=COLUMNS($B$8:B$8), 1, 0)

STEP3：輸入係数行列 M — 単位行列に1が立っているときのみ輸入係数を転記。

• CELL B16=IF(B9=1, $B2, 0)

STEP4：行列 I-M（自給率 = 1 − 輸入率）

• CELL B23=B9-B16

STEP5：行列 (I-M)A — 行列の積なので MMULT 関数を使います。「第1次産業」〜「サービス他」の交点範囲を選択してから入力し、Ctrl+Shift+Enter で配列数式として確定します。

• =MMULT(B23:E26, '投入係数表A'!C4:F7)

STEP6：行列 I-(I-M)A

• CELL B37=B9-B30

新しいシート「逆行列係数表」を用意します（下のリンクからセル A1 にコピー可）。

• 逆行列係数表の骨格をコピー

「第1次産業」〜「サービス他」の交点範囲を選択し、MINVERSE 関数で STEP6 の逆行列を求めます（Ctrl+Shift+Enter で配列数式確定）。

• =MINVERSE('～'!B37:E40)

行計・列計をオートサムで求め、「[I-(I-M)A]^-1」表が完成します。この表をタテに見ると、ある部門に1単位の最終需要が生じたとき各部門に誘発される生産の大きさがわかります。

「[I-(I-M)A]^-1」表から影響力係数と感応度係数を求めます。

• CELL B8（影響力係数）=B7/AVERAGE($B$7:$E$7)
• CELL G3（感応度係数）=F3/AVERAGE($F$3:$F$6)

影響力係数は「その産業に最終需要が1単位生じたとき、自産業や他産業をまきこむ力の相対的な大きさ」を示します（与える側）。 感応度係数は「全産業に1単位の最終需要が生じたとき、その産業が自産業を含む全産業からどれだけ需要を引き受けるかの相対的な大きさ」を示します（受ける側）。 とはいえ、4部門程度の単純化された経済モデルでは係数値の読み取りは大まかなものとなります。