2時点間で「増えた」「減った」を客観視するための、もうひとつの選択肢: スロープグラフ。

COPY ALL

Option Explicit
Option Base 1

Sub DrawSlopeGraph_Main()
' SLOPEGRAPH 2020.0526
' hitorimarketing.net/tools/vba/slope-graph.html
' by hawcas, 2020

Dim target
Dim x As Long, y As Long

Set target = Selection

ActiveSheet.Shapes.AddChart(xlLine).Select
ActiveChart.PlotBy = xlRows

For y = 2 To target.Rows.Count
    If target.Range("b1").Offset(y - 1, 0).Value = "" Or _
        target.Range("c1").Offset(y - 1, 0).Value = "" Then ' AorB=""
        Call SetMarker(y)
    Else
        Call FillLine(y)
    End If
Next y

Call DrawSlopeGraph_Sub1(target)
Call DrawSlopeGraph_Sub2(target)

End Sub

Sub DrawSlopeGraph_Sub1(ByVal t)
' COMPOSE DATALABEL-TEXT

Dim y As Long
Dim size As Long

size = (t.Rows.Count - 1) * 2
For y = 1 To size
    t.Range("c1").Offset(y, 2).Value = y
Next y

Dim str As String

str = "=IF(MOD(ROW(),2)=0, " & _
    "CONCATENATE(OFFSET($A$1,INT(ROW()/2),0), " & _
    """ "", OFFSET($B$1,INT(ROW()/2),0)), " & _
    "CONCATENATE(OFFSET($C$1,INT(ROW()/2),0), " & _
    """ "", OFFSET($A$1,INT(ROW()/2),0)))"
With t.Range("c1").Offset(1, 3)
    .Formula = str
    .AutoFill Destination:=Range(t.Range("c1").Offset(1, 3), _
    t.Range("c1").Offset(size, 3))
End With

End Sub

Sub DrawSlopeGraph_Sub2(ByVal t)
' PUT DATALABELS

Dim y
Dim size As Long
Dim gObj As ChartObject

Set gObj = ActiveChart.Parent
size = (t.Rows.Count - 1) * 2

Dim cnt As Long
Dim str As String

For y = 1 To size Step 2
    cnt = Application.WorksheetFunction.RoundUp(y / 2, 0)
    str = "='" & ActiveSheet.Name & "'!" & _
        t.Range("c1").Offset(y, 3).Address & ":" & _
        t.Range("c1").Offset(y + 1, 3).Address
    With gObj.Chart.SeriesCollection(cnt)
        .HasDataLabels = True
        With .DataLabels
            .Format.TextFrame2.TextRange. _
                InsertChartField msoChartFieldRange, str, 0
            .ShowValue = False
            .ShowRange = True
            .Format.TextFrame2.WordWrap = msoFalse
        End With
    End With
    
'    フォントサイズ・フォント(日欧)を変更する場合
    With gObj.Chart.SeriesCollection(cnt).DataLabels. _
        Format.TextFrame2.TextRange.Font
        .size = 9
        .NameFarEast = "BIZ UDゴシック"
        .Name = "Myriad Pro"
    End With
    
Next y

size = t.Rows.Count - 1
For y = 1 To size
    gObj.Chart.SeriesCollection(y).Points(1).DataLabel.Position = _
    xlLabelPositionLeft
    'gObj.Chart.SeriesCollection(y).DataLabels.Format.TextFrame2.AutoSize = _
    'msoAutoSizeNone
Next y

End Sub

Private Sub SetMarker(ByVal i As Long)
With ActiveChart.FullSeriesCollection(i - 1)
    .ChartType = xlLineMarkers
    .MarkerStyle = xlMarkerStyleDot ' 円の場合:xlMarkerStyleCircle
    .MarkerSize = 5 ' マーカーのサイズ
    .Format.Fill.ForeColor.RGB = RGB(0, 0, 0) ' マーカーの色
    .Format.Line.Visible = msoFalse
End With
End Sub

Private Sub FillLine(ByVal i As Long)
With ActiveChart.FullSeriesCollection(i - 1).Format.Line
    .ForeColor.RGB = RGB(0, 0, 0) ' 線の色
    .Weight = 1 ' 線の太さ
End With
End Sub